Inet.sk

Makrá v OpenOffice.org 04/2008

19. 5. 2008, Programovanie, Július Pastierik, 0 komentárov

Potom, ako sme si v predchádzajúcom dieli ukázali, ako dokážeme v makrách vytvárať (modifikovať) externé dokumenty si dnes ukážeme, ako dokážeme vytvárať nové listy v zošite tabuľkového procesora.

V diskusii k predchádzajúcej časti seriálu o makrách ste sa opýtali, ako je možné vytvárať listy v zošite tabuľkového procesora pomocou makra. Hoci makro nie je zložité, vzniká otázka, ako vlastne zadávať názov listu, pretože tieto sa musia nejako nazývať.

Mohli by sme, podobne ako keď sa zadáva nový list priamo v tabuľkovom procesore, tento názov zadávať cez dialóg alebo cez vstupné pole. Toto riešenie je však pomerne zbytočné, pretože ak už zadávame názov, tak to môžeme urobiť aj mimo prostredia makra – priamo pomocou nástrojov OpenOffice.org.

Z tohto hľadiska sa mi javí ako výhodnejšie, aby sme názov nového listu zadali priamo v makre. Pravdaže, v prípade, že list so zadaným názvom už existuje, nevytvoríme ho:

sub novy_list_zositu
 dim dokument, list as object
 dokument=StarDesktop.CurrentComponent
 
 if not dokument.Sheets.hasByName("Novy_list") then
  list=dokument.createInstance("com.sun.star.sheet.Spreadsheet")
  dokument.Sheets.insertByName("Novy_list", list)
 endif
end sub
Pravdaže, toto riešenie vôbec nie je optimálne, pretože názov je konštantný a v príslušnom dokumente dokážeme takto pridať list iba raz. Preto je lepšie, ak si názov nového listu zadáme do niektorej bunky a pomocou jej obsahu nový list zadefinujeme.

Týmto spôsobom dokážeme automaticky pripravovať povedzme nové listy pre faktúry, ak ich pomocou tabuľkového procesora vytvárame. Nie je problém, aby sme v niektorej bunke mali zapísané posledné číslo faktúry, z ktorej dokážeme odvodiť nové a priamo v makre ho môžeme aj upraviť. Preto si ukážeme príklad makra, kde názov nového listu je ako parameter funkcie, ktorú môžeme priamo zapísať do niektorej bunky v tabuľke.



function f_novy_list_zositu (nazov)
 dim dokument, list as object
 dokument=StarDesktop.CurrentComponent
 
 if not dokument.Sheets.hasByName(nazov) then
  list=dokument.createInstance("com.sun.star.sheet.Spreadsheet")
  dokument.Sheets.insertByName(nazov, list)
 endif
 f_novy_list_zositu=""
end function


V prípade, že nám nevyhovuje ani takéto riešenie, môžeme pridanie nového listu riešiť napríklad tak, že si do niektorej bunky zapíšeme nový názov. Stačí, ak na tejto bunke zostaneme (čím je automaticky vybraná) a spustme makro, ktoré z aktuálneho výberu vyberie prvú bunku a podľa jej obsahu vytvorí nový list.



sub novy_list_zositu_vyber
 dim dokument, list, bunka as object
 dim stlpce, riadky as long
 dim nazov as string

 dokument=ThisComponent.getCurrentSelection()
 stlpce=dokument.getcolumns().Count
 riadky=dokument.getrows().Count
  
 if stlpce<>0 and riadky<>0 then
  bunka=dokument.getCellByPosition(0,0)
  nazov=bunka.getstring()
  dokument=StarDesktop.CurrentComponent
  if not dokument.Sheets.hasByName(nazov) then
   list=dokument.createInstance("com.sun.star.sheet.Spreadsheet")
   dokument.Sheets.insertByName(nazov, list)
  endif
 endif
end sub


V poslednom prípade je vhodné, aby sme si makro pridali buď do panela nástrojov, alebo priradili k nemu klávesovú skratku, lebo jeho spúšťanie cez menu nie je práve najpohodlnejšie.

Aby sme však neboli nespravodliví k tým, ktorí potrebujú zadávať meno listu priamo v makre, pridávame nakoniec aj túto verziu s tým, že budeme aj testovať, či názov nie je prázdny (v takom prípade by sa totiž vytvoril list s názvom „0“).

sub novy_list_zositu
 dim dokument, list as object
 dim nazov as string
 
 dokument=StarDesktop.CurrentComponent
 nazov=InputBox("Názov nového listu: ","Pridanie listu","")
 
 if not dokument.Sheets.hasByName(nazov) and nazov<>"" then
  list=dokument.createInstance("com.sun.star.sheet.Spreadsheet")
  dokument.Sheets.insertByName(nazov, list)
 endif
end sub