Inet.sk - internetový denník

Už v roku 2008 sme uviedli makro pre vytváranie tabuliek v module Writer a pre kopírovanie údajov zošitu z tabuľkového procesora Calc do Writeru (Makrá v OpenOffice.org 02/2008). Na základe otázok niektorých používateľov vznikla potreba upraviť makro tak, aby dokázalo skopírovať tabuľku zo zošitu nie iba od začiatku tabuľky vo Writeri, ale od políčka, v ktorom sa nachádzame.



Z uvedeného prinášame dnes upravenú verziu, ktorá túto skutočnosť zahŕňa. Zároveň sme však ponechali zachované aj ostatné funkcie, teda pokiaľ tabuľka neexistuje, tak sa vytvorí, kontroluje sa, čo sa má vôbec čo kopírovať atď.



Pravdaže, v tomto prípade nemôžeme testovať zhodnosť zdrojovej a cieľovej tabuľky, pretože by to nemalo zmysel a v prípade, že kopírujeme údaje do menšieho počtu riadkov, ako je zdrojová tabuľka, zvyšné riadky sa jednoducho neskopírujú bez akéhokoľvek hlásenia.



Pretože makro je dostatočne okomentované a jeho predchádzajúcej verzii sme venovali už jeden diel seriálu o makrách, uvádzame ďalej už iba zdrojový text:

global bunky_z_calcu_do_writer(0,0)
global stlpce_z_calcu_do_writer, riadky_z_calcu_do_writer as long

sub Kopiruj_tabulku_z_Calc_do_Writer
 dim dokument, bunka as object
 dim stlpec, riadok as long
 dim sprava as string

 if ThisComponent.supportsService("com.sun.star.sheet.SpreadsheetDocument") then
  Dokument=ThisComponent.getCurrentSelection()
  stlpce_z_calcu_do_writer=dokument.getcolumns().Count
  riadky_z_calcu_do_writer=dokument.getrows().Count

  if stlpce_z_calcu_do_writer<>0 and riadky_z_calcu_do_writer<>0 then
   redim preserve bunky_z_calcu_do_writer(riadky_z_calcu_do_writer, stlpce_z_calcu_do_writer)

   for stlpec=0 to stlpce_z_calcu_do_writer-1
    for riadok=0 to riadky_z_calcu_do_writer-1
     bunka=dokument.getCellByPosition(stlpec, riadok)
     bunky_z_calcu_do_writer(riadok+1, stlpec+1)=bunka.getstring()
    next riadok
   next stlpec
  endif
  sprava="Skopírovaných "+str(stlpce_z_calcu_do_writer)+" stĺpcov a "+str(riadky_z_calcu_do_writer)+" riadkov"
  msgbox sprava
 endif
end sub

sub Vytvor_tabulku_z_Calc_do_Writer
 dim dokument, kurzor, tabulka, bunka as object
 dim stlpec, riadok, posun_stlpec, posun_riadok as long
 dim adresa as string

 if ThisComponent.supportsService("com.sun.star.text.TextDocument") and _
  stlpce_z_calcu_do_writer<>0 and riadky_z_calcu_do_writer<>0 then
  dokument=StarDesktop.CurrentComponent
  kurzor=ThisComponent.currentcontroller.getViewCursor()

  on error goto Nie_sme_v_tabulke

  tabulka=kurzor.TextTable

  adresa=kurzor.Cell.CellName ' Adresa je povedzme "C5", z toho si musíte oddeliť znak stĺpca a previesť ich na čísla – posun
  posun_stlpec=asc(left(adresa, 1))-65 ' ASCII kód znaku mínus "A" mínus jedna, aby sme dostali posun
  posun_riadok=val(right(adresa, len(adresa)-1))-1 ' Číslo riadku mínus jedna, aby sme dostali posun
 
  mame_tabulku:
  on error resume next

  for riadok=1 to riadky_z_calcu_do_writer
   for stlpec=1 to stlpce_z_calcu_do_writer
    adresa=chr(64+stlpec+posun_stlpec)&(riadok+posun_riadok)
    bunka=tabulka.getCellByName(adresa)
    bunka.String= bunky_z_calcu_do_writer(riadok, stlpec)
   next stlpec
  next riadok
 else
  msgbox "V schránke nie je žiadna tabuľka"
 endif

 exit sub

 Nie_sme_v_tabulke:
  tabulka=dokument.createInstance("com.sun.star.text.TextTable")
  tabulka.initialize(riadky_z_calcu_do_writer, stlpce_z_calcu_do_writer)
  dokument.Text.insertTextContent(kurzor, tabulka, false)
  goto mame_tabulku
end sub

13. 12. 2009 Július Pastierik Programovanie Komentáre