Archív Inet.sk Pôvodný autor: Július Pastierik
26. 01. 2011 o 00:00 1783x

Makrá v OpenOffice.org: Hromadná tlač súborov

Potrebujete v OpenOffice.org hromadne tlačiť súbory (doc, odt, xls, ...) bez toho, aby ste ich museli otvárať? Ukážeme si makro, ktoré to urobí za nás.
Makrá v OpenOffice.org: Hromadná tlač súborov

Viacerí používatelia sa stretávajú s problémom, že potrebujú tlačiť viacero súborov (niekedy aj stovky), ktoré sú napr. generované externými programami a, samozrejme, ich manuálne otváranie a následná tlač je iba „manuálna rutinná nuda“.

Preto si uvedieme makro, ktoré bude tieto problémy riešiť za nás. Pri jeho tvorbe budeme vychádzať z predpokladu, že súbory, ktoré chceme tlačiť, sa nachádzajú v jednom adresári, pričom si však budeme môcť určiť typy (prípony), ktoré vlastne chceme tlačiť. Na zadanie týchto parametrov si preto zadefinujeme dialógové okno, kde zadáme cestu a prípony oddelené medzerami. Aby sme nemuseli tento postup vždy opakovať, v makre zabudujeme nástroj na odpamätanie zadaných údajov, takže pri budúcom spustení nám bude už stačiť stlačiť tlačidlo typu „Tlač“.



Vlastnú tlač musíme riešiť otvorením súboru v OpenOffice.org. Aby nám obsah tlačených súborov „nepreblikával“ po obrazovke, budeme ich otvárať neviditeľne. Pretože však otváranie aj tlač sú pomerne pomalé, budeme v okne, v ktorom zadávame adresár a prípony pri vlastnej tlači vypisovať názov práve tlačeného súboru, čím uvidíme priebeh. Samozrejme, zatvorením tohto okna zistíme, že tlač je z hľadiska OpenOffice.org ukončená (či čaká v tlačovej fronte, to je už iná záležitosť). Vlastnú tlač prevedieme na defaultnú tlačiareň.

dim oDlg

REM Funkcia pre zistenie jazyka OO.o
function Jazyk_OOo as string
 dim ConfigProvider, MasterKey as object
 dim NodePath(0) as new com.sun.star.beans.PropertyValue

 NodePath(0).Name = "nodepath"
 NodePath(0).Value = "org.openoffice.Setup/L10N/"

 ConfigProvider = createUnoService("com.sun.star.configuration.ConfigurationProvider")
 MasterKey = ConfigProvider.createInstanceWithArguments("com.sun.star.configuration.ConfigurationAccess", NodePath())
 Jazyk_OOo = left(MasterKey.getByName("ooLocale"), 2) '"sk", "cs", ...
end function

REM Procedúra pre nastavenie jazyka dialógu
Sub Set_jazyk_Dialogu(oDlg, sNazov, sZahlavie)
 dim riadok, premenna, definicia as string
 dim rovna as integer
 dim sf, inStream, inFile ' Pre čítanie z lokalizačného súboru

 on error resume next

 if fileexists(sNazov) then ' Ak lokalizačný súbor existuje, tak načítame definície do premenných
  sf = createUnoService("com.sun.star.ucb.SimpleFileAccess")
  inStream = sf.openFileRead(sNazov)
  inFile = createUnoService("com.sun.star.io.TextInputStream")
  inFile.InputStream = inStream
  inFile.Encoding = "UTF-8" ' lokalizačný súbor musí byť v UTF-8, inak nebude dobrá diakritika 

  Do While not inFile.IsEOF
   riadok = inFile.readLine ' namiesto Line Input #subor, riadok
   rovna=instr(riadok,"=")
   if rovna<>0 then
    premenna=trim(left(riadok,rovna-1)) ' Budeme ignorovať medzery
    definicia=trim(right(riadok,len(riadok)-rovna))
    if premenna=sZahlavie then
     oDlg.Title=definicia
    else
     oDlg.model.getByName(premenna).setpropertyvalue("Label",definicia)
    end if
   end if
  loop
  ' Zatvorenie definičného súboru – namiesto close #subor
  inStream.closeInput
  inFile.closeInput
 end if
end sub

REM Funkcia pre načítanie nastavených reťazcov (adresár, typy súborov) zo súboru
function nacitaj_subor(sNazov as string) as string
 dim vysledok, riadok, nazov as string
 dim sf, inStream, inFile ' Pre čítanie z lokalizačného súboru
 
 kde=basiclibraries.getLibraryLinkURL("JP_tlac_subory") ' Adresár, kde je rozšírenie nainštalované
 nazov=left(kde,len(kde)-10)+sNazov+".txt" ' Súbor s príslušnými textami

 vysledok=""
 
 if fileexists(nazov) then ' Ak súbor existuje, tak načítame definície do premennej
  sf = createUnoService("com.sun.star.ucb.SimpleFileAccess")
  inStream = sf.openFileRead(nazov)
  inFile = createUnoService("com.sun.star.io.TextInputStream")
  inFile.InputStream = inStream
  inFile.Encoding = "UTF-8" ' Súbor musí byť v UTF-8, inak nebude dobrá diakritika
 
  Do While not inFile.IsEOF
   riadok = inFile.readLine ' namiesto Line Input #subor, riadok
   vysledok=vysledok+riadok
  loop
  ' Zatvorenie definičného súboru – namiesto close #subor
  inStream.closeInput
  inFile.closeInput
 end if
 nacitaj_subor=vysledok
end function

REM Procedúra pre zápis nastavených reťazcov (adresár, typy súborov) do súboru
sub zapis_subor(sNazov, retazec as string)
 dim sf, outStream, outFile ' Pre čítanie z lokalizačného súboru
 
 kde=basiclibraries.getLibraryLinkURL("JP_tlac_subory") ' Adresár, kde je rozšírenie nainštalované
 nazov=left(kde,len(kde)-10)+sNazov+".txt" ' Súbor s príslušnými textami

 sf = createUnoService("com.sun.star.ucb.SimpleFileAccess")
 outStream = sf.openFileWrite(nazov)
 outFile = createUnoService("com.sun.star.io.TextOutputStream")
 outFile.OutputStream = outStream
 outFile.Encoding = "UTF-8" ' Súbor bude v UTF-8 aby bola dobrá diakritika
 outStream.truncate() ' Vymazanie predchádzajúceho obsahu
 outFile.writeString(retazec)
 outStream.closeOutput
 outFile.closeOutput
end sub

REM Vlastná tlač
sub TlacSubor(sCesta as string, sSubor as string)
 dim sNazov$ : sNazov=sCesta+sSubor ' Názov súboru zložíme z adresára a vlastného názvu
 dim aMediaDesc(0) as New com.sun.star.beans.PropertyValue
 dim oDokument as object
 
 on error resume next ' Prevencia chýb
 
 aMediaDesc(0).Name = "Hidden" ' Súbory budeme otvárať neviditeľne
 aMediaDesc(0).Value = TRUE
 oDokument=StarDesktop.loadComponentFromURL(sNazov, "_blank", 0, aMediaDesc()) ' Otvoríme súbor
 
 aMediaDesc(0).Name = "Wait" ' Tlač musíme synchronizovať, inak OO.o havaruje
 aMediaDesc(0).Value = TRUE
 oDokument.print(aMediaDesc()) ' Vytlačíme súbor
 oDokument.close(True) ' Zatvoríme súbor
end sub

sub ZadajAdresar
 dim oAdresarDialog : oAdresarDialog=CreateUnoService("com.sun.star.ui.dialogs.FolderPicker")
 dim oAdresarExistuje : oAdresarExistuje=createUnoService("com.sun.star.ucb.SimpleFileAccess")
 dim sAdresar$ : sAdresar=oDlg.model.TextAdresar.Text
 dim sAdresarURL$ : sAdresarURL=ConvertToUrl(sAdresar)

 if oAdresarExistuje.Exists(sAdresarURL) then oAdresarDialog.SetDisplayDirectory(sAdresarURL)
 if oAdresarDialog.Execute() then
  sAdresar=ConvertFromUrl(oAdresarDialog.GetDirectory())
  oDlg.model.TextAdresar.Text=sAdresar
 end if
end sub

REM Otvorenie dialógu, výber adresára so súbormi a ich postupná tlač
sub TlacVsetkySubory
 dim sAdresar$ : sAdresar=trim(nacitaj_subor("adresar"))
 dim sPripony$ : sPripony=nacitaj_subor("pripony")
 dim sAdresarURL$ : sAdresarURL=ConvertToUrl(sAdresar)
 dim sSubor$, sPom$
 
 dim aPrintDesc(0) as New com.sun.star.beans.PropertyValue
 
 DialogLibraries.LoadLibrary("JP_tlac_subory")
 oDlg=CreateUnoDialog(DialogLibraries.JP_tlac_subory.DialogTlacSubory) ' Dialóg pre zadanie adresára, typov súborov a vlastnú tlač
 
 kde=basiclibraries.getLibraryLinkURL("JP_tlac_subory") ' Adresár, kde je rozšírenie nainštalované
 nazov=left(kde,len(kde)-10)+"jp_tlac_subory_"+Jazyk_OOo+".txt" ' Súbor s jazykovou lokalizáciou
 Set_jazyk_dialogu(oDlg, nazov, "DialogTlacSubory") ' Nastavenie jazyka dialógu
 
 oDlg.model.TextAdresar.Text=sAdresar ' Nastavenie odpamätanej cesty
 oDlg.model.Pripony.Text=sPripony ' Nastavenie odpamätaných prípon
 
 if oDlg.Execute() then ' Stlačené tlačidlo "Tlač"
  oDlg.setVisible(true)
  sAdresar=oDlg.model.TextAdresar.Text ' Zadaný adresár
  sAdresarURL=ConvertToUrl(sAdresar)+"/"
  sPripony=lcase(" "+trim(oDlg.model.Pripony.Text)+" ") ' Zadané prípony prevedieme na malé písmená a ohraničíme medzerami
  zapis_subor("adresar", sAdresar) ' Odpamätanie adresára
  zapis_subor("pripony", sPripony) ' Odpamätanie prípon
  sSubor=dir(sAdresarURL, 0)
  While sSubor<>"" ' Pre všetky súbory zo zadaného adresára
   rem Zistenie prípony aktuálneho súboru
   j=0
   for i=1 to len(sSubor)
    if mid(sSubor,i,1)="." then j=i ' Vyhľadanie poslednej bodky v názve
   next i
   if j<>0 then ' Súbor má zadanú príponu
    j=len(sSubor)-j
    sPom=" "+lcase(right(sSubor,j))+" " ' Vlastná prípona plus medzery pre jednoznačné hľadanie
    if instr(sPripony, sPom)<>0 then ' Ak je prípona v zozname, súbor vytlačíme
     oDlg.model.TextSubor.Text=sSubor ' Zobrazenie názvu súboru v dialógu
     TlacSubor(sAdresarURL, sSubor) ' Súbor neviditeľne otvoríme a vytlačíme
    end if
   end if
   sSubor=dir() ' Ďalší súbor
  Wend
 end if
 oDlg.dispose() ' Zatvorenie dialógu
end sub

Novinky a inšpirácie

Z nášho blogu

Prečítajte si novinky, inšpirácie a dôležité informácie zo sveta webhostingu a technológií.

Píšete podpore cez AI? Nech píše len podstatné Oznamy
17. 11. 2026

Píšete podpore cez AI? Nech píše len podstatné

Čoraz viac ľudí dnes píše podpore cez AI asistenta a je to dobrý nápad. Má to len jeden háčik: bez pokynov AI rada vyrobí dlhý príbeh. Po...

Čítať viac
Novinky na Inet.sk (11 / 2026) - Nová ponuka Novinky
05. 11. 2026

Novinky na Inet.sk (11 / 2026) - Nová ponuka

Predstavujeme novú ponuku webhostingu s jednoduchým rebríkom veľkostí, nové menu a stránku Stav domény a WHOIS. Pribudla aj podpora PHP 8...

Čítať viac
Bezpečnostné aktualizácie PHP: Chráňte svoj web pred hrozbami Oznamy
21. 10. 2026

Bezpečnostné aktualizácie PHP: Chráňte svoj web pred hrozbami

Vývojársky tím PHP vydal dôležité bezpečnostné záplaty pre všetky oficiálne podporované verzie PHP 8. Na našich serveroch sme nezaváhali ...

Čítať viac
Gmail končí s funkciou „Odoslať ako“ pre cudzie e-mailové adresy. Čo to znamená pre vás? Oznamy
01. 10. 2026

Gmail končí s funkciou „Odoslať ako“ pre cudzie e-mailové adresy. Čo to znamená pre vás?

Google oznámil, že v januári 2027 zruší v Gmaile funkciu „Odoslať ako“ (Send as) pre e-mailové adresy od iných poskytovateľov. Ak ste si ...

Čítať viac

Podpora klientom

Máte ďalšie otázky?

Nezúfajte, pripravili sme pre Vás jednoduché odpovede na najdôležitejšie otázky, ktoré od našich klientov dostávame.

Zistiť viac

Naše výhody

Prečo si nás vybrať?

Našim klientom ponúkame až 30-dňovú záruku vrátenia peňazí.

Sme skutočný slovenský webhosting

Slovenská
firma

Nepatríme pod žiadnu nadnárodnú spoločnosť, sme malá rodinná firma.

Na nás sa môžete kedykoľvek spoľahnúť

Dlhoročné
skúsenosti

Na slovenskom trhu pôsobíme už viac ako 20 rokov, sme overená značka.

Naši prví zákazníci sú stále s nami

Spokojní
zákazníci

Naši zákazníci sú ako naša rodina, preto nám verí už viac ako 1250 klientov.

Maximálna bezpečnosť

Maximálna
bezpečnosť

Chránime Vás pred útokmi i SPAMom. U nás sú Vaše dáta v bezpečí.

Prozákaznícka podpora

Ochotná
podpora

Zakladáme si na individuálnom prístupe, preto Vám vždy radi pomôžeme.

Kvalita a dobrá cena

Férová
cena

Cena pri obnove je rovnaká ako pri objednávke. Nezdražujeme po prvom roku a bez skrytých poplatkov.

U nás sa Vám nič nestratí

Pravidelné
zálohovanie

Vaše dáta zálohujeme každý deň, dostupné sú aj zálohy z pred niekoľkých mesiacov.

Svižný Admin Panel nájdete len u nás

Prehľadný
Admin Panel

Máme rýchly a prehľadný Admin Panel, ktorý zvládne používať naozaj každý.

Správa používateľov

Správa
používateľov

Spravujte svoje projekty bez akýchkoľvek obáv s kolegami alebo externými partnermi.

Máme zľavy pre verných klientov

Vernostné
zľavy

Verní klienti u nás automaticky získavajú 15 % zľavu na každú ďalšiu objednávku.

My Vás nebudeme obmedzovať

Bez
obmedzení

Neobmedzujeme počet databáz, e-mailov, ftp a ani prenos dát.

Hosting pre WordPress

WordPress
na 1 klik

Nainštalujte si obľúbené redakčné systémy rýchlo a jednoducho.

Referencie

Spokojní zákazníci

Pozrite sa, čo o nás povedali naši klienti. Neváhajte a pridajte sa k nám ešte dnes.

Auto 100
Bystricoviny
eCall Slovakia
Filip Jančík
Frost
Merkury Broker
Mi:Su Design
Mesto Nitra
Pro Clienta
Schneider Lekáreň
Vego Marketing
Mesto Zlaté Moravce

Všetky ceny sú uvádzané bez DPH
© 2006 - 2026, Inet.sk, s. r. o., Všetky práva vyhradené

Na našej stránke používame "cookies". Vďaka nim sledujeme návštevnosť, prispôsobujeme reklamu a používateľské nastavenia, čo zlepšuje Váš zážitok z našej stránky. Súhlasíte s ich spracovaním?
Vlastné nastavenia cookies