Veľké množstvo používateľov (nielen) OpenOffice.org pri zámene naráža na dosť zásadný problém – pri náhrade reťazca za nový sa veľkosť prvého písmena nového reťazca nemení. Takto sa môže stať, že na začiatku vety sa „zrazu“ objavia slová s malým počiatočným písmenom. Samozrejme, tento problém sa dá riešiť napríklad tým, že sa bude reťazec vyhľadávať a nahrádzať v dvoch krokoch – raz s malým a druhýkrát s veľkým prvým písmenom, pričom, pravdaže, je potrebné pamätať na zaškrtnutie príznaku rozoznávania veľkosti písmen a treba zmeniť ako vyhľadávaný, tak aj reťazec, ktorým nájdený text nahrádzame.
Uvedený postup je dosť komplikovaný, navyše je pri ňom potrebné pamätať na veľa nastavení. Preto si naprogramujeme makro, ktoré to bude riešiť za nás – ak nájdený reťazec bude začínať na malé písmeno, tak sa nastaví malé písmeno aj do reťazca, ktorým ho nahrádzame a, naopak, ak nájdený reťazec bude začínať na veľké písmeno, tak sa nastaví veľké písmeno aj do reťazca, ktorým ho nahrádzame.
Pretože budeme riešiť problematiku nahrádzania reťazcov, je škoda nevyužiť dialóg na to, aby sme do neho nevložili aj iné možnosti. Ako ďalší problém je totiž to, že niekedy chceme nahradiť v nájdenom reťazci iba jeho vnútornú časť za inú, pričom vopred nevieme, koľkokrát sa táto časť bude nachádzať. Ako typický príklad môže byť vyhľadávanie textov, ktoré autor nesprávne zvýraznil tzv. prekladaním (t.j. za každé písmeno vložil medzeru) – v nájdenom reťazci potrebujeme medzeru zameniť za prázdny reťazec.

Z uvedených dôvodov musí dialóg obsahovať tri textové vstupy – klasické vstupy „Hľadať“, „Nahradiť za“, ku ktorým pribudne špeciálny vstup „V reťazci“. Pokiaľ zadáme tento reťazec, budú sa náhrady hľadaného reťazca prevádzať iba vo vnútri reťazcov „V reťazci“.
A aby sme dialóg mohli využívať podobne, ako klasický dialóg pre zámeny, doplníme ho o nastavenia „Regulárne výrazy“, „Iba celé slová“, „Rozlišovať veľké písmená“ či tlačidlá „Nájsť“, „Nahradiť“, „Nahradiť všetko“. Okrem toho ho rozšírime o už spomínanú možnosť nastavenia „Ponechať veľké písmená“.
Pre uvedenie problematiky by mohol tento úvod stačiť a preto si teraz uvedieme prvú časť makier, ktoré sa budú venovať nastaveniu a spusteniu dialógového okna špeciálnych zámen.
REM Premenné si zadefinujeme ako global, aby sa pamätali aj pri ďalšom spustení
global zamen_V_retazci, zamen_Hladat, zamen_Nahradit_za as string
global zamen_Regularne_vyrazy, zamen_Cele_slova, zamen_Velke_pismena, zamen_Ponechat_velke as boolean
dim oDlg, oNasiel as object
dim sPopis0, sPopis1, sPopis2, sPopis3, sPopis4 as string ' Výpisy pri hľadaní a nahrádzaní
REM Funkcia pre zistenie jazyka OO.o
function Jazyk_OOo as string
dim ConfigProvider, MasterKey as object
dim NodePath(0) as new com.sun.star.beans.PropertyValue
NodePath(0).Name = "nodepath"
NodePath(0).Value = "org.openoffice.Setup/L10N/"
ConfigProvider = createUnoService("com.sun.star.configuration.ConfigurationProvider")
MasterKey = ConfigProvider.createInstanceWithArguments("com.sun.star.configuration.ConfigurationAccess", NodePath())
Jazyk_OOo = left(MasterKey.getByName("ooLocale"), 2) '"sk", "cs", ...
end function
REM Procedúra pre nastavenie jazyka dialógu
Sub Set_jazyk_dialogu(oDlg, sNazov, sZahlavie)
dim riadok, premenna, definicia as string
dim rovna as integer
dim sf, inStream, inFile ' Pre čítanie z lokalizačného súboru
on error resume next
if fileexists(sNazov) then ' Ak lokalizačný súbor existuje, tak načítame definície do premenných
sf = createUnoService("com.sun.star.ucb.SimpleFileAccess")
inStream = sf.openFileRead(sNazov)
inFile = createUnoService("com.sun.star.io.TextInputStream")
inFile.InputStream = inStream
inFile.Encoding = "UTF-8" ' lokalizačný súbor musí byť v UTF-8, inak nebude dobrá diakritika
Do While not inFile.IsEOF
riadok = inFile.readLine ' namiesto Line Input #subor, riadok
rovna=instr(riadok,"=")
if rovna<>0 then
premenna=trim(left(riadok,rovna-1)) ' Budeme ignorovať medzery
definicia=trim(right(riadok,len(riadok)-rovna))
select case premenna
case "Popis0" ' Výpisy pri hľadaní a nahrádzaní
sPopis0=Definicia
case "Popis1"
sPopis1=Definicia
case "Popis2"
sPopis2=Definicia
case "Popis3"
sPopis3=Definicia
case "Popis4"
sPopis4=Definicia
case sZahlavie
oDlg.Title=definicia ' Nadpis dialógu
case else
oDlg.model.getByName(premenna).setpropertyvalue("Label",definicia) ' položky dialógu
end select
end if
loop
' Zatvorenie definičného súboru – namiesto close #subor
inStream.closeInput
inFile.closeInput
end if
end sub
REM Procedúra pre inicializáciu dialógu
sub Init_dialog_zameny
' Nastavenie jazyka dialógu a výpisov
sPopis0="JP Špeciálne hľadanie"
sPopis1="OpenOffice.org hľadal až po koniec dokumentu. Chcete pokračovať od začiatku?"
sPopis2="Hľadaný reťazec nenájdený."
sPopis3="Hľadaný reťazec bol"
sPopis4="krát nahradený."
kde=basiclibraries.getLibraryLinkURL("JP_specialna_zamena") ' Adresár, kde je rozšírenie nainštalované
nazov=left(kde,len(kde)-10)+"JP_specialna_zamena_"+Jazyk_OOo+".txt" ' Súbor s jazykovou lokalizáciou
Set_jazyk_dialogu(oDlg, nazov, "Dialog_Zamena") ' Nastavenie jazyka dialógu
REM Inicializácia prvkov dialógu podľa predtým nastavených parametrov
REM Hľadané a nahrádzané reťazce
oDlg.model.V_retazci.Text = zamen_V_retazci
oDlg.model.Hladat.Text = zamen_Hladat
oDlg.model.Nahradit_za.Text = zamen_Nahradit_za
' Hľadanie regulárnych výrazov
if zamen_Regularne_vyrazy then
oDlg.model.Regularne_vyrazy.State=1
else
oDlg.model.Regularne_vyrazy.State=0
endif
' Hľadanie celých slov
if zamen_Cele_slova then
oDlg.model.Cele_slova.State=1
else
oDlg.model.Cele_slova.State=0
endif
' Hľadanie s rozoznávaním veľkosti znakov
if zamen_Velke_pismena then
oDlg.model.Velke_pismena.State=1
else
oDlg.model.Velke_pismena.State=0
endif
' Špeciálne nahrádzanie so zachovaním veľkosti prvého písmena
if zamen_Ponechat_velke then
oDlg.model.Ponechat_velke.State=1
else
oDlg.model.Ponechat_velke.State=0
endif
end sub
REM Makro, ktoré zneviditeľní dialóg – t.j. nastaví, že sa má ukončiť čakací cyklus (volané stlačením klávesy "Koniec" v dialógu)
sub Koniec_Zamen_Initiated
oDlg.setVisible(false )' Zneviditeľnenie dialógu
end sub
sub Specialne_zamen
dim oPrazdne as object
oNasiel=oPrazdne ' Aby premenná oNasiel bola Null
DialogLibraries.LoadLibrary("JP_specialna_zamena")
oDlg=CreateUnoDialog(DialogLibraries.JP_specialna_zamena.Dialog_Zamena)
Init_dialog_zameny
oDlg.setVisible(true) ' zviditeľnenie dialógu – namiesto dlg.Execute(), aby sa dalo paralelne pracovať s textom
while oDlg.isVisible() ' Cyklus, ktorý čaká na stlačenie klávesy "Koniec" v dialógu (kým je dialóg viditeľný)
wait 500 ' Časová medzera 500 milisekúnd (0,5 sec) na to, aby sa dalo paralelne pracovať s dokumentom
wend
oDlg.dispose() ' Zatvorenie dialógu
oNasiel=oPrazdne ' Aby premenná oNasiel bola Null
end sub