Funkcie a procedúry
V minulom dieli sme si ukázali makro pre vymazávanie viacnásobných medzier, kde sme pridali aj vymazávanie nepotrebných znakov na začiatku či konci odstavca a pod. Pokiaľ si dobre všimnete toto makro, zistíte, že sa tam viac krát opakuje vlastne tá istá postupnosť týchto príkazov:
Vymena.SearchRegularExpression=True
Vymena.SearchString= … ' hľadaný reťazec
Vymena.ReplaceString= … ' reťazec, ktorým nahrádzame
kolko=Dokument.replaceAll(Vymena)
V prípade ďalších zámen (ktoré budeme ešte programovať) sa takýto program zbytočne predlžuje a stráca prehľadnosť. Preto je vhodné, aby sme často opakované postupnosti rovnakých príkazov zadefinovali osobitne ako funkciu alebo procedúru, ktoré spoločným názvom nazývame aj podprogramy. Procedúru už vlastne používame, pretože aj už naprogramované makrá pre výmenu viacnásobných medzier sú vlastne procedúry. Je to vlastne akoby definícia nového príkazu. Samotná definícia má takýto obecný tvar:
SUB názov(zoznam parametrov)
…
END SUB
Funkcie nám tiež nie sú neznáme, pretože poznáme napr. matematické funkcie a pod. V našom makre pre výmenu viacnásobných medzier sme používali napr. systémovú funkciu Dokument.replaceAll. Samotná definícia má takýto obecný tvar:
FUNCTION názov(zoznam parametrov) AS typ výsledku
…
názov=výsledok
END FUNCTION
Ako vidíme, vo funkcii musíme mať aspoň jeden špeciálny priraďovací príkaz, ktorým priradíme jej výsledok do názvu funkcie. Dosť však bolo teórie, pozrime sa na naše makro pre výmenu viacnásobných medzier. Uvedené štyri riadky by sme mohli naprogramovať potom takto:
FUNCTION Vymen(Co, Za as string, Regularne as Boolean) as long
rem Funkcia vymení reťazec Co za reťazec Za a vráti počet výmien
rem Regularne - určuje, či vyhľadávaný výraz je (TRUE) alebo nie je (FALSE) regulárny výraz
rem Ako výsledok bude počet zámen
Vymena.SearchString=Co
Vymena.ReplaceString=Za
Vymena.SearchRegularExpression=Regularne
Vymen=Dokument.replaceAll(Vymena) ' Do názvu funkcie priraďujeme počet výmen
END FUNCTION
Vlastnú procedúru pre zámenu môžeme teraz naprogramovať takto:
SUB Viacnasobna_medzera
DIM kolko AS Long
DIM NM AS string
NM=chr$(&HA0) ' Nezalomiteľná medzera (ctrl+space)
' Výmena viacnásobných medzier za jednoduchú
kolko=Vymen(" +"," ",TRUE)
' Kombinácie nezalomiteľných a zalomiteľných medzier
kolko=kolko+Vymen(" "+NM+" |"+NM+" | "+NM,NM,TRUE)
' Kombinácie tabelátorov a medzier
kolko=kolko+Vymen(" t |t | t","t",TRUE)
' Medzery na začiatku a konci odstavca
kolko=kolko+Vymen("^[:space:]*|[:space:]*$","",TRUE)
' Tabelátory na začiatku a konci odstavca
kolko=kolko+Vymen("^t*|t*$","",TRUE)
msgbox("Nahradených "+kolko+" viacnásobných medzier.",0,"Viacnásobne medzery")
END SUB
Ako vidíme, makro sa naozaj zjednodušilo a obsahuje okrem poznámok presne deväť riadkov. Pravdaže, dá sa zapísať ešte kratšie – na päť riadkov s použitím jedného jediného priraďovacieho príkazu, ale to je už trochu na úkor čitateľnosti a prehľadnosti:
SUB Viacnasobna_medzera
DIM kolko AS Long
DIM NM AS string
NM=chr$(&HA0) ' Nezalomiteľná medzera (ctrl+space)
kolko=Vymen(" +"," ",TRUE)+Vymen(" "+NM+" |"+NM+" | "+NM,NM,TRUE)+Vymen(" t |t | t","t",TRUE)+Vymen("^[:space:]*|[:space:]*$","",TRUE)+Vymen("^t*|t*$","",TRUE)
msgbox("Nahradených "+kolko+" viacnásobných medzier.",0,"Viacnásobne medzery")
END SUB
Alebo pre absolutistov ešte kratšie na tri riadky:
SUB Viacnasobna_medzera
DIM NM AS string
NM=chr$(&HA0) ' Nezalomiteľná medzera (ctrl+space)
msgbox("Nahradených "+Vymen(" +"," ",TRUE)+Vymen(" "+NM+" |"+NM+" | "+NM,NM,TRUE)+Vymen(" t |t | t","t",TRUE)+Vymen("^[:space:]*|[:space:]*$","",TRUE)+Vymen("^t*|t*$","",TRUE)+" viacnásobných medzier.",0,"Viacnásobne medzery")
END SUB
Alebo ak chcete, tak absolútne na jeden riadok:
SUB Viacnasobna_medzera
msgbox("Nahradených "+Vymen(" +"," ",TRUE)+Vymen(" "+chr$(&HA0)+" |"+chr$(&HA0)+" | "+chr$(&HA0),chr$(&HA0),TRUE)+Vymen(" t |t | t","t",TRUE)+Vymen("^[:space:]*|[:space:]*$","",TRUE)+Vymen("^t*|t*$","",TRUE)+" viacnásobných medzier.",0,"Viacnásobne medzery")
END SUB
Posledné úpravy však nevedú (ak vôbec vedú) k zrýchleniu podprogramu a sú preto určené iba ako ukážka možností volania funkcií s prípadným šetrením pamäte, ktoré sme získali definíciou menšieho (alebo nulového) počtu premenných.
Ak sa pozrieme na zadefinované podprogramy zistíme, že sme kdesi „stratili“ definíciu premennej Vymena a vlastne nikde nepriraďujeme výmenu k aktuálnemu dokumentu. Niečo nám tam teda ešte chýba. Najprv si však povedzme, ako je to vôbec s premennými – ktoré poznáme iba vo vnútri podprogramu a ktoré aj mimo? Je to jednoduché – všetko záleží od miesta, kde ich definujeme. Ak zadefinujeme premenné iba vo vnútri podprogramu, potom ich poznáme iba tam – môžeme ich nazvať lokálne premenné. Ak ich zadefinujeme „vonku“, poznáme ich všade – môžeme ich nazvať ako globálne, alebo spoločné premenné.
Takže v tomto zmysle teraz zadefinujeme chýbajúce premenné a následne priradíme aktuálny dokument. Celé makro zo všetkými funkciami a procedúrami potom môžeme naprogramovať napríklad takto:
REM Definície spoločných premenných sú úplne pred definíciou podprogramov
dim Dokument, Vymena as object
' Nezalomiteľnú medzeru budeme používať aj v iných makrách, preto presunieme definíciu sem
dim NM as string
' V osobitnej procedúre inicializujeme spoločné premenné.
' Túto procedúru musíme potom volať ako prvú, inak neurobíme potrebné priradenia.
sub Init
rem Inicializácia spoločných premenných
Dokument=ThisComponent
Vymena=Dokument.createReplaceDescriptor()
NM=chr$(&HA0) ' Nezalomiteľná medzera – hexadecimálny kód A0
end sub
FUNCTION Vymen(Co, Za as string, Regularne as Boolean) as long
rem Funkcia vymení reťazec Co za reťazec Za a vráti počet výmien
rem Regularne - určuje, či vyhľadávaný výraz je (TRUE) alebo nie je (FALSE) regulárny výraz
rem Ako výsledok bude počet zámen
Vymena.SearchString=Co
Vymena.ReplaceString=Za
Vymena.SearchRegularExpression=Regularne
Vymen=Dokument.replaceAll(Vymena) ' Do názvu funkcie priraďujeme počet výmen
END FUNCTION
SUB Viacnasobna_medzera
DIM kolko AS Long
' Inicializácia spoločných premenných
Init
' Výmena viacnásobných medzier za jednoduchú
kolko=Vymen(" +"," ",TRUE)
' Kombinácie nezalomiteľných a zalomiteľných medzier
kolko=kolko+Vymen(" "+NM+" |"+NM+" | "+NM,NM,TRUE)
' Kombinácie tabelátorov a medzier
kolko=kolko+Vymen(" t |t | t","t",TRUE)
' Medzery na začiatku a konci odstavca
kolko=kolko+Vymen("^[:space:]*|[:space:]*$","",TRUE)
' Tabelátory na začiatku a konci odstavca
kolko=kolko+Vymen("^t*|t*$","",TRUE)
msgbox("Nahradených "+kolko+" viacnásobných medzier.",0,"Viacnásobne medzery")
END SUB
Toto je minule sľúbené makro pre výmenu viacnásobných medzier na osem riadkov. A hoci to tak nevyzerá, ešte stále to nie je jeho posledná verzia. Napokon, stále platia staré programátorské zákony – v každom programe je aspoň jedna chyba a v každom programe je aspoň jeden riadok zbytočný (len to neberte absolútne, lebo potom by sme nemali čo programovať :-).
Na budúce: Pridávame nové funkcie, alebo konečne aj niečo iné, ako viacnásobné medzery.
