„Nezalomiteľné“ dátumy
Ďalším problémom, s ktorým sa pri dodržiavaní typografických pravidiel môžeme stretnúť. Je vkladanie nezalomiteľných medzier za číslice v dátumoch. Najjednoduchšie je tento problému vyriešiť tak, že automaticky vložíme nezalomiteľnú medzeru za každé číslo, ktoré končí znakom bodky:
sub Nezalomitelne_datumy
dim Cislovky() as string
dim i, kolko as long
Cislovky()=array("1.","2.","3.","4.","5.","6.","7.","8.","9.","0.")
kolko=0
for i=lbound(Cislovky()) to ubound (Cislovky())
kolko=kolko+Vymen(Cislovky(i)+" ",Cislovky(i)+NM,false,false,false)
next i
msgbox("Nahradených "+kolko+" zalomiteľných medzier.",0,"Nezalomiteľné dátumy")
end sub
Pravdaže, toto riešenie nie je optimálne, pretože vloží nezalomiteľnú medzeru za úplne každé radové číslo bez ohľadu na to, kde sa vyskytuje. Pokiaľ ho teda budeme mať napr. na konci vety (napr. „ … a tento pretekár skončil 123.“, úplne zbytočne nám tu vloží nezalomiteľnú medzeru. Tento problém by sme mohli vyriešiť tak, že budeme postupne testovať všetky dvojice číslic „1. 1“, „1. 2“, … „0. 0“. napr. takto:
sub Nezalomitelne_datumy
dim Cislovky() as string
dim i, j, kolko as long
Cislovky()=array("1","2","3","4","5","6","7","8","9","0")
kolko=0
for i=lbound(Cislovky()) to ubound (Cislovky())
for j=lbound(Cislovky()) to ubound (Cislovky())
kolko=kolko+Vymen(Cislovky(i)+". "+Cislovky(j),Cislovky(i)+"."+NM+Cislovky(j),false,false,false)
next j
next i
msgbox("Nahradených "+kolko+" zalomiteľných medzier.",0,"Nezalomiteľné dátumy")
end sub
Toto riešenie je však veľmi pomalé, pretože celý dokument prehľadáme presne sto krát, kým neotestujeme a neopravíme všetky kombinácie a preto je v praxi viac-menej nepoužiteľné. Pravdaže, pri vyhľadávaní by sme mohli použiť regulárne výrazy, napr. „[0-9]\. [0-9]“, pomocou ktorých dokážeme vyhľadať všetky potrebné kombinácie na jeden krok. Problém je však v tom, ako zabezpečiť výmenu medzery, ktorá sa nachádza niekde uprostred hľadaného výrazu, pričom ani nevieme, ktorú konkrétnu dvojicu číslic takto nájdeme.
Toto sa dá riešiť tak, že keď nájdeme niektorú dvojicu dátumových číslic, následne v nej pomocou funkcií pre prácu s reťazcami opravíme potrebnú medzeru a až potom takto pripraveným reťazcom nahradíme pôvodný. Na to nám však nebude stačiť štandardná metóda pre zámenu, ktorú sme doteraz používali:
Vymena=Dokument.createReplaceDescriptor()
ale najprv musíme vyhľadať potrebný reťazec metódou pre hľadanie:
Hladaj=Dokument.createSearchDescriptor()
Preto sa teraz musíme vrátiť k definícii premenných a procedúre „Init“, aby sme tam doplnili požadované údaje:
REM Definície spoločných premenných sú úplne pred definíciou podprogramov
dim Dokument, Vymena, Hladaj as object
dim NM as string
sub Init
Dokument=ThisComponent
Vymena=Dokument.createReplaceDescriptor()
Hladaj=Dokument.createSearchDescriptor()
NM=chr$(&HA0) ' Nezalomiteľná medzera – hexadecimálny kód A0
end sub
Po nájdení budeme vo vnútri dátumu vymieňať zalomiteľnú medzeru za nezalomiteľnú. Na takéto zámeny si zadefinujeme obecnú funkciu, pomocou ktorej dokážeme zameniť ľubovoľný vnútorný reťazec za iný, pretože v takomto tvare sa nám bude hodiť aj pre iné účely:
function Zamen_Vo_Vnutri (V_Com, Co, Za as string) as string
REM Funkcia vyhľadá v reťazci V_Com reťazec Co a nahradí ho reťazcom Za.
REM Ak tento reťazec nenájde, ponechá vo výsledku pôvodný reťazec V_Com.
dim pom as string
dim i, j as long
REM Pre prípad, že sa reťazec nenájde, necháme vo výsledku pôvodný reťazec
pom=V_Com
REM pozícia hľadaného reťazca
i=instr(V_Com,Co)
REM veľkosť zvyšku pravej strany pôvodného reťazca, ktorá je za hľadaným reťazcom
j=len(V_Com)-i-len(Co)+1
REM ak sa reťazec Co našiel, je jeho pozícia väčšia ako 0
if i>0 then
REM do výsledku priradíme ľavú časť pôvodného reťazca plus nahrádzaný reťazec
pom=left(V_Com,i-1)+Za
REM ak je za hľadaným reťazcom ešte nejaký zvyšok pôvodného reťazca
if j>0 then
REM do výsledku priradíme aj tento zvyšok
pom=pom+right(V_Com,j)
end if
end if
Zamen_Vo_Vnutri=pom
end function
Teraz už môžeme zadefinovať vlastnú funkciu na výmenu, kde najprv nájdeme hľadaný výraz, potom v ňom zameníme vnútorný reťazec za iný a nakoniec upraveným reťazcom nahradíme pôvodný. Pravdaže, pri hľadaní využijeme možnosť nastavenia hľadania pomocou regulárnych výrazov, celých slov a rozlišovania veľkosti písmen. Ako výsledok tejto funkcie bude počet prevedených zámen.
function Vymen_hladanim(V_Com, Co, Za as string, Regularne, Cele_slova, Velke_pismena as Boolean) as long
REM procedúra vyhľadá reťazec V_Com, pričom až v skutočne nájdenom reťazci zamení vnútorný reťazec Co za reťazec Za.
dim nasiel as object
dim kolko as long
Hladaj.searchString=V_Com
Hladaj.SearchRegularExpression=Regularne
Hladaj.SearchWords=Cele_slova
Hladaj.SearchCaseSensitive=Velke_pismena
kolko=0
REM objekt s nájdeným reťazcom priradíme do premennej Nasiel
nasiel = Dokument.findFirst(Hladaj)
rem opakuj, pokiaľ tento objekt obsahuje nejaké údaje
Do While NOT isNull(nasiel)
rem ak sa našiel reťazec
if len(nasiel.String)>0 then
rem ak sa našiel reťazec, tak urobíme zámenu a výsledkom nahradíme pôvodný reťazec
nasiel.String=Zamen_Vo_Vnutri(nasiel.String,Co,Za)
kolko=kolko+1
end if
rem vyhľadáme ďalší reťazec
nasiel = Dokument.findNext( nasiel.End, Hladaj)
Loop
Vymen_hladanim=kolko
end function
Procedúra pre výmenu nezalomiteľných medzier vo vnútri dátumov potom môže vyzerať takto:
sub Nezalomitelne_datumy
dim kolko as long
kolko=Vymen_hladanim("[0-9]\. [0-9]"," ",NM,true,false,false)
msgbox("Nahradených "+kolko+" zalomiteľných medzier.",0,"Nezalomiteľné dátumy")
end sub
V prípade, že máme v texte uvedený dátum s údajom dňa, mesiaca a roku nedokáže toto makro vložiť nezalomiteľnú medzeru medzi číselný údaj mesiaca a roku. Toto však môžeme riešiť opakovaným vyhľadávaním:
sub Nezalomitelne_datumy
dim kolko as long
kolko=Vymen_hladanim("[0-9]\. [0-9]"," ",NM,true,false,false)
kolko=kolko+Vymen_hladanim("[0-9]\. [0-9]"," ",NM,true,false,false)
msgbox("Nahradených "+kolko+" zalomiteľných medzier.",0,"Nezalomiteľné dátumy")
end sub
Na budúce: Ďalšie nezalomiteľné medzery, alebo ako to všetko skomplikovať.
