Makrá v OpenOffice.org 4/VII. – Pružná nezalomiteľná medzera 2.

Naposledy sme si uviedli tri rôzne možnosti vkladania medzier za jednoznakové predložky a spojky – obyčajné medzery (vtedy vlastne netreba nič robiť, pretože to je štandardne nastavená hodnota v OpenOffice.org), nahrádzanie tejto medzery znakom nezalomiteľnej medzery („Non Break Space“ – hexadecimálny kód A0) alebo vkladanie znaku spájania slov („Word Joiner“ – hexadecimálny kód 2060) pred obyčajnú medzeru.

Osobne môžem potvrdiť, že skoro každodenne potrebujem používať všetky tri uvedené „typy“ medzier, takže sa to bude týkať aj ostatných používateľov. Aj preto som na konci minulého dielu uviedol tieto tri vety:

V tomto riadku sú všetky medzery obyčajné.

V tomto riadku sú všetky medzery nedeliteľné.

V⁠ tomto⁠ riadku⁠ je⁠ pred⁠ každou⁠ medzerou⁠ znak⁠ „Word⁠ Joiner“.
Aby si každý vedel predstaviť, že nie vždy sa nám môže hodiť to najlepšie riešenie. Pokiaľ potrebujem uverejniť napríklad tento článok na stránkach www.inet.sk, používam bežné nezalomiteľné medzery, ktoré sa správne zobrazujú vo všetkých prehliadačoch, pretože by si ich používatelia Internet Explorera či Opery (iné som neoveroval) nemohli dobre prečítať. To isté chcem dosiahnuť pri zasielaní správ rôznym externým organizáciám (v RTF či DOC formáte) a tam používam ako nezalomiteľné, tak aj obyčajné medzery.

Ako vidíme, problematika týchto znakov nie je práve jednoduchá a preto je dobré, ak si nastavíme možnosť rôzneho prepínania medzi nimi. Za týmto účelom si zadefinujeme dialóg „Dialog_Nezalomitelne_Predlozky“ (teraz som už vynechal znak podčiarnika na konci, pretože tento dialóg skutočne používam už dlhšiu dobu). Nebudeme sa už venovať položkám, ktoré sme už spomínali a priamo pristúpime k pridávaniu prepínacích položiek. Tieto nájdeme ukryté v známych symboloch „krúžkov“. Je dobré, ak ich zadávame za sebou. V zozname vlastností si musíme navyše všímať hodnotu „Poradie aktivácie“, pretože s týmto číslom budeme ešte zaobchádzať (v našom príklade to bude 3 a 4, pretože som tieto položky zadal v tomto poradí). Pravdaže, toto poradie sa dá meniť, ale treba si dať pozor, pretože OpenOffice.org automaticky prečísluje ostatné položky v prípade, že dôjde ku konfliktu.

Pretože niektorí používatelia budú chcieť, aby sa im makro pre vkladanie nezalomiteľných medzier za jednoznakové predložky a spojky automaticky spúšťalo pri otvorení dokumentu (ale iní – ako napr. ja zase nie), pridáme si do nášho dialógu ešte ďalšie zaškrtávacie okienko, ktorým budeme nastavovať aj tento parameter. Celkové dialógové okno môže potom po spustení vyzerať napríklad takto:



Teraz nám už nič nebráni v tom, aby sme si naprogramovali jednotlivé funkcie pre vlastnú prácu s dialógovým oknom a vkladaním nezalomiteľných medzier. Pravdaže, vzhľadom na väčší počet nastavovaných parametrov je potrebné vymazať príslušný dátový súbor, v ktorom máme zapamätané doterajšie nastavenia (však sa hneď pri prvom spustení obnoví):

global ObsluhaDokumentu, ObsluhaKlavesnice as object
global PosledneSlovo, OddelovaceSlov, JednoznakovePredlozky as string
global Priznaky_nezalomitelne_medzery(3) as integer
global Obsluhovat_Klavesnicu as boolean

function Subor_nezalomitelne_predlozky as string
 Subor_nezalomitelne_predlozky="file:///c:/Program files/OpenOffice.org 2.0/Nezalomitelne_Predlozky.dat"
end function

sub Init_zoznam_predloziek
 JednoznakovePredlozky="AiIkKoOsSuUvVzZ"
 if Priznaky_nezalomitelne_medzery(2)=1 then
  JednoznakovePredlozky="a"+JednoznakovePredlozky
 endif
end sub

sub Uloz_nastavenie_predlozky
 dim i, subor as integer

 subor = Freefile
 open Subor_nezalomitelne_predlozky for Output as #subor
 for i=1 to 3
  print #subor,str(Priznaky_nezalomitelne_medzery(i))
 next i
 close #subor
end sub

sub Citaj_nastavenie_predlozky
 dim i, subor as integer
 dim riadok as string
 ' Inicializácia na štandardné štandardné hodnoty
 for i=1 to 3
  Priznaky_nezalomitelne_medzery(i)=1
 next i

 ' Ak nastavovací súbor neexistuje, vutvoríme ho a uložíme do neho štandardné hodnoty
 if not fileexists(Subor_nezalomitelne_predlozky) then
   Uloz_nastavenie_predlozky
 endif

 ' Teraz súbor určite existuje - načítame ho
 subor = Freefile
  open Subor_nezalomitelne_predlozky for Input as #subor
 i=0
 While not eof(subor)
  i=i+1
  Line Input #subor, riadok
  Priznaky_nezalomitelne_medzery(i)=val(riadok)
 wend
 close #subor

 ' Ak v súbore chýbal nejaký údaj, tak to opravíme
 if i<3 then
  Uloz_nastavenie_predlozky
 endif
 Init_zoznam_predloziek
end sub

sub init_dialog_predlozky(oDialog as object)
 Citaj_nastavenie_predlozky
 oDialog.model.Automaticky.State=Priznaky_nezalomitelne_medzery(1)
 oDialog.model.Za_spojku_a.State=Priznaky_nezalomitelne_medzery(2)
 oDialog.model.TabIndex=3
 oDialog.model.TabIndex=4
 select case Priznaky_nezalomitelne_medzery(3)
  case 2
   oDialog.model.Volba1.State=0
   oDialog.model.Volba2.State=1
  case else
   oDialog.model.Volba1.State=1
   oDialog.model.Volba2.State=0
 end select
end sub

sub zapis_dialog_predlozky(oDialog as object)
 Priznaky_nezalomitelne_medzery(1)=oDialog.model.Automaticky.State
 Priznaky_nezalomitelne_medzery(2)=oDialog.model.Za_spojku_a.State
 if oDialog.model.Volba1.State=1 then
  Priznaky_nezalomitelne_medzery(3)=1
 else
  Priznaky_nezalomitelne_medzery(3)=2
 endif
 Uloz_nastavenie_predlozky
 ' A ešte podľa nového nastavenia zmeníme zoznam predložiek
 Init_zoznam_predloziek
end sub

sub NastavPriznakyNezalomitelnePredlozky
dim dlg as object

 DialogLibraries.LoadLibrary("Vlastne_makra")

 dlg=CreateUnoDialog(DialogLibraries.Vlastne_makra.Dialog_Nezalomitelne_Predlozky)
 init_dialog_predlozky(dlg)

 if dlg.Execute()=1 then
  zapis_dialog_predlozky(dlg)
 endif
 dlg.dispose()
end sub

sub SpustiObsluhuKlavesnice
 on error goto next
 if ThisComponent.supportsService("com.sun.star.text.TextDocument") then
  ' Sme v textovom dokumente, kde chceme nahrádzať medzery
  Obsluhovat_Klavesnicu=True
  PosledneSlovo = ""
  ' medzera, nezalomiteľná medzera, tabelátor, CR, LF
  OddelovaceSlov=" "+chr(&HA0)+chr(&H09)+chr(&H0A)+chr(&H0D)
  ' pomlčka, lomítko, bodka, čiarka, výkričník, otáznik, bodkočiarka, trojbodka
  OddelovaceSlov=OddelovaceSlov+"-/.,!?;…"
  ' zátvorky
  OddelovaceSlov=OddelovaceSlov+"()[]{}"
  ObsluhaDokumentu = ThisComponent.getCurrentController
  ObsluhaKlavesnice = createUnoListener("Klavesnica_","com.sun.star.awt.XKeyHandler")
  ObsluhaDokumentu.addKeyHandler(ObsluhaKlavesnice)
 endif
end sub

sub UkonciObsluhuKlavesnice
 on error goto next
 if ThisComponent.supportsService("com.sun.star.text.TextDocument") then
  ' Sme v textovom dokumente a chceme ukončiť obsluhu klávesnice
   ObsluhaDokumentu.removeKeyHandler(ObsluhaKlavesnice)
   PosledneSlovo = ""
 endif
end sub

function VlozZnak(Retazec as string)
' Na aktuálnu pozíciu v dokumente vložíme reťazec
dim ViditelnyKurzor, AktualnyText, AktualnyKurzor as object

 ViditelnyKurzor = ThisComponent.getCurrentController().getViewCursor()
 AktualnyText = ThisComponent.getText()
 AktualnyKurzor = AktualnyText.createTextCursorByRange(ViditelnyKurzor.getStart() )
 AktualnyText.insertString(AktualnyKurzor.getStart(), Retazec, true)

end function

function Klavesnica_KeyPressed(StlacenaKlavesa) as boolean
' Obsluha stlačenej klávesy
dim Obsluzena as boolean

 'Predpokláme, že nebudeme vkladať nezalomiteľnú medzeru
 Obsluzena=False
 if instr(OddelovaceSlov,StlacenaKlavesa.KeyChar)<>0 then
  ' Došli sme na koniec slova
  if Obsluhovat_Klavesnicu then
   if ZistiPredlozku and (StlacenaKlavesa.KeyChar=" ") then
    ' Je to predložka, ktorá končí zalomiteľnou medzerou - túto nahradíme
    if Priznaky_nezalomitelne_medzery(3)=1 then
     VlozZnak(chr$(&HA0)) ' No Break Space
     ' Sami sme vložili medzeru - obslúžili sme stlačenú klávesu
     Obsluzena=true
    else
     VlozZnak(chr$(&H2060)) ' Word Joiner
     ' V tomto prípade sa musí ešte vložiť aj zadaná medzera a preto sme neobslúžili stlačenú klávesu
    endif
   endif
  endif
  PosledneSlovo=""
 else
  ' Ešte musíme otestovať riadiace znaky, ktoré nebudeme sledovať v zadávanom slove
  select case StlacenaKlavesa.KeyChar
   case chr$(&H00) to chr$(&H07)
    PosledneSlovo=""
   case chr$(&H08) ' BS
    if len(PosledneSlovo)>0 then
     PosledneSlovo=left(PosledneSlovo,len(PosledneSlovo)-1)
    else
     PosledneSlovo=""
    endif
   case chr$(&H09) to chr$(&H1F)
    PosledneSlovo=""
   case chr$(&H20) to chr$(&H7E)
    PosledneSlovo=PosledneSlovo+StlacenaKlavesa.KeyChar
   case chr$(&H7F) ' CTRL BS
    PosledneSlovo=""
   case else
    PosledneSlovo=PosledneSlovo+StlacenaKlavesa.KeyChar
  end select
 endif
 Klavesnica_KeyPressed=Obsluzena
end function

function Klavesnica_KeyReleased(StlacenaKlavesa) as boolean
' Obsluha pustenej klávesy
 Klavesnica_KeyReleased = False
end function

function ZistiPredlozku as boolean
dim JePredlozka as boolean

 JePredlozka=false
 if len(PosledneSlovo)=1 then
  ' Ak je to jednoznakové slovo, tak to môže byť predložka
  JePredlozka=instr(1,JednoznakovePredlozky,PosledneSlovo,0)
 endif
 ZistiPredlozku=JePredlozka

end function
Teraz k vlastným prepínačom. Inicializovali sme ich týmito dvomi príkazmi:

oDialog.model.TabIndex=3
oDialog.model.TabIndex=4
OpenOffice.org sa správa tak, že ak uvedieme bezprostredne za sebou bez prerušenia iným príkazom zoznam prepínačov, považuje ich za jeden zoznam a bude prepínať automaticky medzi nimi, t.j. označením jednej položky zruší označenie inej. K uvedeným funkciám ešte musíme naprogramovať aj podporné obslužné programy, resp. ich priradiť k akciám ako je otvorenie či zatvorenie súboru, ale tomu všetkému sa budeme venovať až na budúce.

Na budúce: Niekoľko programov na záver, alebo oddýchnime si na príjemných dovolenkách.