Makrá v OpenOffice.org 5/X. – Formátovanie dokumentu 2

Už v štvrtom dieli tretej časti tohto seriálu o programovaní makier v OpenOffice.org (Makrá v OpenOffice.org 3/IV. – Práca so súbormi 2) sme si ukázali, ako si môžeme ukladať nastavenia do súboru. Vtedy sme, pre jednoduchosť, použili iba priamu cestu do konkrétneho adresára:

Subor_nezalomitelne_predlozky="file:///c:/Program files/OpenOffice.org 2.0/Nezalomitelne_Predlozky.dat"
Toto riešenie má, pravdaže, niekoľko nedostatkov. Konkrétne uvedený príklad je hádam ten najhorší, aký sa dá pri programovaní zvoliť (a práve preto je dobré, že sa zvolil, aby sa ukázali jeho všetky nedostatky).

Ako základ je to, že pokiaľ si nainštalujeme novú verziu OpenOffice.org, tak sa zmení aj jeho kmeňový adresár „OpenOffice.org 2.0“ - v súčasnosti je to pre najnovšiu verziu „OpenOffice.org 2.1“. Po odinštalovaní pôvodnej verzie, pravdaže, môžeme pôvodný adresár s príslušnými súbormi ponechať, vedie to však k zníženiu prehľadnosti.

Iná možnosť je zmeniť vlastné makro a presunúť inicializačný definičný súbor na nové miesto. Toto by sme však museli pracne robiť pri každej novej inštalácii, takže to tiež nie je práve vyhovujúce riešenie.

Pravdaže, ako miesto pre ukladanie inicializačných definičných súborov si môžeme zvoliť aj iný adresár, než je práve adresár, kde sa nachádza program OpenOffice.org, napríklad:

Subor_nezalomitelne_predlozky="file:///c:/Program files/OpenOffice.org init_subory/Nezalomitelne_Predlozky.dat"

Toto riešenie je nezávislé od inštalácie OpenOffice.org. Má však ešte stále jednu nevýhodu – pokiaľ sa pri počítači strieda viacej používateľov, nemôže si každý nastaviť svoje vlastné podmienky, čo môže byť niekedy veľmi nevyhovujúce. Preto je najlepšie také riešenie, kde si každý používateľ uloží svoje nastavenia do osobitného adresára, ktorý mu poskytuje OpenOffice.org v rámci príslušného operačného systému.

Na tento účel máme v rámci používateľského rozhrania jazyka StarOffice Basic k dispozícii objekt „com.sun.star.util.PathSettings“, ktorý nám poskytne všetky potrebné cesty a ktorý môžeme inicializovať napríklad nasledovným spôsobom:

dim cesty as object
cesty=CreateUnoService("com.sun.star.util.PathSettings")
Objektová premenná „cesty“ obsahuje teraz nasledovné údaje:

Backup – Cesta ku kópiám dokumentov, ktoré boli automaticky zálohované.
Basic – Cesta k makrám a dialógom, ktoré sú napísané v jazyku Basic. Táto hodnota môže obsahovať viacej ciest, ktoré sú oddelené bodkočiarkou.
Favorite – Cesta k obľúbeným položkám.
Gallery – Cesta ku galériovej databáze a multimediálnym súborom. Táto hodnota môže obsahovať viacej ciest, ktoré sú oddelené bodkočiarkou.
Graphic – Táto cesta sa zobrazuje v dialógu pre otvorenie alebo ukladanie grafických objektov.
Help – Cesta k nápovedným súborom OpenOffice.org.
Module – Cesta k jednotlivým modulom OpenOffice.org.
Storage – Cesta k informáciám o pošte, súborom správ, FTP serveri a pod.
Temp – Cesta k dočasným súborom.
Template – Cesta k šablónam, ktoré máme zaradené do OpenOffice.org. Táto hodnota môže obsahovať viacej ciest, ktoré sú oddelené bodkočiarkou.
UserConfig – Cesta k adresáru pre používateľské nastavenia.
Work – Cesta k používateľskej pracovnej zložka. Používa sa v dialógu pri otváraní a zatváraní súborov a môže byť používateľom aj zmenená.

Pre zistenie všetkých ciest si môžeme napísať takéto jednoduché makro:

sub zoznam_ciest

 dim cesty as object
 dim zoznam, CR as string
 CR=chr$(10)

 cesty=CreateUnoService("com.sun.star.util.PathSettings")

 zoznam="Backup: "+CR+cesty.Backup+CR+CR
 zoznam=zoznam+"Basic: "+CR+cesty.Basic+CR+CR
 zoznam=zoznam+"Favorite: "+CR+cesty.Favorite+CR+CR
 zoznam=zoznam+"Gallery: "+CR+cesty.Gallery+CR+CR
 zoznam=zoznam+"Graphic: "+CR+cesty.Graphic+CR+CR
 zoznam=zoznam+"Help: "+CR+cesty.Help+CR+CR
 zoznam=zoznam+"Module: "+CR+cesty.Module+CR+CR
 zoznam=zoznam+"Storage: "+CR+cesty.Storage+CR+CR
 zoznam=zoznam+"Temp: "+CR+cesty.Temp+CR+CR
 zoznam=zoznam+"Template: "+CR+cesty.Template+CR+CR
 zoznam=zoznam+"UserConfig: "+CR+cesty.UserConfig+CR+CR
 zoznam=zoznam+"Work: "+CR+cesty.Work
 msgbox zoznam

end sub
Pokiaľ chcete zmeniť adresár, ktorý nájdeme v adresári „Work“, môžeme si na to naprogramovať takúto jednoduchú procedúru:

sub zmen_work (novy_work as string)
 REM Predpokladáme, že cesta nie je zadaná vo všeobecnom URL formáte
 dim cesty as object
 cesty=CreateUnoService("com.sun.star.util.PathSettings")
 cesty.work=ConvertToURL(novy_work)
end sub
Alebo takúto procedúru:

sub zmen_work (novy_work as string)
 REM Predpokladáme, že cesta je uložená vo všeobecnom URL formáte
 dim cesty as object
 cesty=CreateUnoService("com.sun.star.util.PathSettings")
 cesty.work=novy_work
end sub
Pre ukladanie našich nastavení sa javí, že bude najvhodnejšie používať adresár, kde sú uložené aj ostatné používateľské nastavenia (UserConfig). Funkciu pre zistenie názvu inicializačného súboru môžeme potom naprogramovať napríklad takto:

function inicializacny_subor (nazov_suboru as string) as string
 REM Funkcia vracia názov inicializačného súboru v „UserConfig“ adresári aktuálneho používateľa
 dim cesty as object
 cesty=CreateUnoService("com.sun.star.util.PathSettings")
 inicializacny_subor=cesty.UserConfig+"/"+nazov_suboru
end function
Na budúce: Nastavujeme dialóg pre formátovanie dokumentu pre každého používateľa, alebo ako to urobiť, aby každý mohol mať naraz k dispozícii aj viacej nastavení.