OpenOffice.org má pre bežnú prácu s textom pripravený horný aj dolný index. Tieto indexy sú nastavené teak, že veľkosť písma je 58% bežnej veľkosti a index je zarovnaný k hornej alebo spodnej časti textu.
Toto však častokrát nepostačuje a v takomto prípade musíme siahnuť po makre, pomocou ktorého dokážeme nastavovať indexy pokročilejšie. OpenOffice.org nám v tomto smere ponúka možnosť percentuálneho nastavenia veľkosti indexu od 1% až po 100% a možnosť odsadenia indexu od 0% až po 101% – hodnota 101% v skutočnosti znamená, že sa index zarovná k hornej alebo spodnej časti textu. To, či sa jedná o horný alebo spodný index je určené percentom odsadenia – kladné hodnoty určujú, že sa jedná o index horný, záporné, že sa jedná o index dolný.
Pretože nastavovanie pomocou kladných a záporných čísiel by bolo používateľsky nepríjemné, vytvoríme si pre nastavovanie dialóg, kde budeme nastavovať osobitne hodnoty pre horný a osobitne hodnoty pre dolný index. Samozrejme, príslušný prepočet na záporné číslo budeme robiť priamo v makre.
Aby sa makrom pracovalo pohodlne, nastavíme ho tak, že dialóg bude môcť byť spustený aj počas písania textu. Aby sme nemuseli najčastejšie používané hodnoty nastavovať ručne, umožníme ich uloženie a načítanie zo súboru.
Pravdaže, makro budeme znovu programovať tak, že to je jazykovo lokalizované rozšírenie a preto súčasťou budú aj procedúry pre jazykovú lokalizáciu. Pre jednoduchosť budeme procedúru pre načítavanie jazykovej lokalizácie zároveň používať aj pre načítavanie odpamätaných hodnôt indexov.
Aby sme nemuseli nastavovať indexy iba číselne, pripravíme si zároveň celý rad procedúr, pomocou ktorých dokážeme zmeniť (zväčšiť aj zmenšiť) príslušné hodnoty o 10% a o 1%. Pravdaže, zároveň si pripravíme aj funkcie pre nastavenie indexov podľa nastavených hodnôt aj vtedy, ak nebudeme mať otvorený dialóg a nesmieme zabudnúť ani na funkciu nastavenia „normálneho“ textu.
Ako vidíme, je toho viac než dosť a preto je iba samozrejmé, že vlastné makro bude pomerne rozsiahle a preto jeho zdrojové texty prinesieme vo viacerých dieloch tohto seriálu. Dnes si ukážeme hlavné deklarácie a základné procedúry.
REM Makro pre nastavenie horných a spodných indexov
REM Globálne premenné pre pamätanie nastavenia
global JP_Nastav_index_HI_V as integer
global JP_Nastav_index_HI_O as integer
global JP_Nastav_index_DI_V as integer
global JP_Nastav_index_DI_O as integer
global JP_Nastav_Index_dialog as boolean
dim JP_Nastav_index_dlg as object
REM Funkcia pre zistenie jazyka OO.o
function Jazyk_OOo as string
dim ConfigProvider, MasterKey as object
dim NodePath(0) as new com.sun.star.beans.PropertyValue
NodePath(0).Name = "nodepath"
NodePath(0).Value = "org.openoffice.Setup/L10N/"
ConfigProvider = createUnoService("com.sun.star.configuration.ConfigurationProvider")
MasterKey = ConfigProvider.createInstanceWithArguments("com.sun.star.configuration.ConfigurationAccess", NodePath())
Jazyk_OOo = left(MasterKey.getByName("ooLocale"),2) '"sk", "cs", ...
end function
REM Procedúra pre nastavenie jazyka dialógu
Sub Set_jazyk_dialogu(oDlg, sNazov, sZahlavie)
dim riadok, premenna, definicia as string
dim rovna as integer
dim sf, inStream, inFile ' Pre čítanie z lokalizačného súboru
on error resume next
if fileexists(sNazov) then ' Ak lokalizačný súbor existuje, tak načítame definície do premenných
sf = createUnoService("com.sun.star.ucb.SimpleFileAccess")
inStream = sf.openFileRead(sNazov)
inFile = createUnoService("com.sun.star.io.TextInputStream")
inFile.InputStream = inStream
inFile.Encoding = "UTF-8" ' lokalizačný súbor musí byť v UTF-8, inak nebude dobrá diakritika
Do While not inFile.IsEOF
riadok = trim(inFile.readLine) ' namiesto Line Input #subor, riadok
rovna=instr(riadok,"=")
if rovna<>0 then
premenna=trim(left(riadok,rovna-1)) ' Budeme ignorovať medzery
definicia=trim(right(riadok,len(riadok)-rovna))
select case premenna
case sZahlavie
oDlg.Title=definicia
case "HI_V"
JP_Nastav_index_HI_V=val(definicia) ' Nastavenie veľkosti horného indexu
case "HI_O"
JP_Nastav_index_HI_O=val(definicia) ' Nastavenie odsadenia horného indexu
case "DI_V"
JP_Nastav_index_DI_V=val(definicia) ' Nastavenie veľkosti dolného indexu
case "DI_O"
JP_Nastav_index_DI_O=val(definicia) ' Nastavenie odsadenia dolného indexu
case else
oDlg.model.getByName(premenna).setpropertyvalue("Label",definicia)
end select
end if
loop
' Zatvorenie definičného súboru – namiesto close #subor
inStream.closeInput
inFile.closeInput
end if
end sub
REM Procedúra pre nastavenie nenulových hodnôt indexov
sub Testuj_nulove_hodnoty
dim kde, nazov as string
REM V nastavení indexov nesmú byť nulové hodnoty pre veľkosť a záporné hodnoty pre odsadenie.
REM Pokiaľ čo len jedna je, nastavíme štandardné, ako ich používa OO.o a potom sa ich pokúsime nastaviť zo súboru
if JP_Nastav_index_HI_V<=0 or JP_Nastav_index_DI_V<=0 or JP_Nastav_index_HI_O<0 or JP_Nastav_index_DI_O<0 then
JP_Nastav_index_HI_V=58 ' Štandardná veľkosť horného indexu je 58%
JP_Nastav_index_HI_O=101 ' Štandardné odsadenie horného indexu je 101%, prípustné je aj 0%
JP_Nastav_index_DI_V=58 ' Štandardná veľkosť dolného indexu je 58%
JP_Nastav_index_DI_O=101 ' Štandardné odsadenie dolného indexu je –101%, prípustné je aj 0%
kde=basiclibraries.getLibraryLinkURL("JP_Nastav_index") ' Adresár, kde je rozšírenie nainštalované
nazov=left(kde,len(kde)-10)+"JP_index_setup.txt" ' Súbor s definíciou indexov
Set_jazyk_dialogu(JP_Nastav_index_dlg, nazov, "Dialog_Nastav_index") ' Nastavenie indexov
end if
if JP_Nastav_Index_dialog then ' Ak je viditeľný dialóg pre nastavenie indexu
JP_Nastav_index_dlg.model.HI_O.text=trim(str(JP_Nastav_index_HI_O)) ' Nastavenie indexu do dialógu
JP_Nastav_index_dlg.model.DI_O.text=trim(str(JP_Nastav_index_DI_O)) ' Nastavenie indexu do dialógu
JP_Nastav_index_dlg.model.HI_V.text=trim(str(JP_Nastav_index_HI_V)) ' Nastavenie indexu do dialógu
JP_Nastav_index_dlg.model.DI_V.text=trim(str(JP_Nastav_index_DI_V)) ' Nastavenie indexu do dialógu
end if
end sub
REM Makro, ktoré zneviditeľní dialóg – t.j. nastaví, že sa má ukončiť čakací cyklus (volané stlačením klávesy "Koniec" v dialógu)
sub Koniec_Nastav_index
JP_Nastav_Index_dialog=false ' Príznak, že dialóg je neviditeľný
JP_Nastav_index_dlg.setVisible(false )' Zneviditeľnenie dialógu
end sub
REM Procedúra pre načítanie hodnôt indexov zo súboru (volané stlačením klávesy "Načítaj" v dialógu)
sub Nacitaj_Nastav_index
dim kde, nazov as string
kde=basiclibraries.getLibraryLinkURL("JP_Nastav_index") ' Adresár, kde je rozšírenie nainštalované
nazov=left(kde,len(kde)-10)+"JP_index_setup.txt" ' Súbor s definíciou indexov
Set_jazyk_dialogu(JP_Nastav_index_dlg, nazov, "Dialog_Nastav_index") ' Nastavenie indexov
JP_Nastav_index_dlg.model.HI_O.text=trim(str(JP_Nastav_index_HI_O)) ' Nastavenie indexu do dialógu
JP_Nastav_index_dlg.model.DI_O.text=trim(str(JP_Nastav_index_DI_O)) ' Nastavenie indexu do dialógu
JP_Nastav_index_dlg.model.HI_V.text=trim(str(JP_Nastav_index_HI_V)) ' Nastavenie indexu do dialógu
JP_Nastav_index_dlg.model.DI_V.text=trim(str(JP_Nastav_index_DI_V)) ' Nastavenie indexu do dialógu
end sub
REM Makro, ktoré uloží indexy do súboru (volané stlačením klávesy "Ulož" v dialógu)
sub Uloz_Nastav_index
dim kde, sNazov, riadok as string
dim sf, outStream, outFile ' Pre čítanie a zápis do lokalizačného súboru
kde=basiclibraries.getLibraryLinkURL("JP_Nastav_index") ' Adresár, kde je rozšírenie nainštalované
sNazov=left(kde,len(kde)-10)+"JP_index_setup.txt" ' Súbor s definíciou indexov
sf = createUnoService("com.sun.star.ucb.SimpleFileAccess")
outStream = sf.openFileWrite(sNazov)
outFile = createUnoService("com.sun.star.io.TextOutputStream")
outFile.OutputStream = outStream
outFile.Encoding = "UTF-8" ' Súbor bude v UTF-8 aby bola dobrá diakritika
outStream.truncate() ' Vymazanie predchádzajúceho obsahu
riadok="HI_V="+trim((JP_Nastav_index_dlg.model.HI_V.text)) ' Veľkosť horného indexu
outFile.writeString(riadok+chr(13))
riadok="HI_O="+trim((JP_Nastav_index_dlg.model.HI_O.text)) ' Veľkosť horného indexu
outFile.writeString(riadok+chr(13))
riadok="DI_V="+trim((JP_Nastav_index_dlg.model.DI_V.text)) ' Veľkosť horného indexu
outFile.writeString(riadok+chr(13))
riadok="DI_O="+trim((JP_Nastav_index_dlg.model.DI_O.text)) ' Veľkosť horného indexu
outFile.writeString(riadok)
outStream.closeOutput
outFile.closeOutput
end sub
REM Procedúra pre definovanie indexov pomocou dialógu
sub Definuj_Horny_Dolny_Index
DialogLibraries.LoadLibrary("JP_Nastav_index") ' Inicializácvia knižnice
JP_Nastav_index_dlg=CreateUnoDialog(DialogLibraries.JP_Nastav_index.Dialog_Nastav_index) ' Inicializácia dialógu
kde=basiclibraries.getLibraryLinkURL("JP_Nastav_index") ' Adresár, kde je rozšírenie nainštalované
nazov=left(kde,len(kde)-10)+"JP_Nastav_index_"+Jazyk_OOo+".txt" ' Súbor s jazykovou lokalizáciou
Set_jazyk_dialogu(JP_Nastav_index_dlg, nazov, "Dialog_Nastav_index") ' Nastavenie jazyka dialógu
JP_Nastav_index_dlg.setVisible(true) ' zviditeľnenie dialógu – namiesto JP_Nastav_index_dlg.Execute(), aby sa dalo paralelne pracovať s textom
JP_Nastav_Index_dialog=true ' Príznak, že dialóg je viditeľný
Testuj_nulove_hodnoty ' Testovanie a nastavenie veľkosti a odsadenia indexov
while JP_Nastav_index_dlg.isVisible() ' Cyklus, ktorý čaká na stlačenie klávesy "Koniec" v dialógu (kým je dialóg viditeľný)
wait 500 ' Časová medzera 500 milisekúnd (0,5 sec) na to, aby sa dalo paralelne pracovať s dokumentom
wend
JP_Nastav_Index_dialog=false ' Príznak, že dialóg je neviditeľný
JP_Nastav_index_dlg.dispose()
end sub
