Pre jednoduché vysvetlenie pojmu „ruby“ text uvedieme, že je to text, ktorý sa nachádza v bezprostrednej blízkosti pri tzv. základnom texte a používa sa ako jeho anotácia, výslovnosť a pod. Jeho veľkosť je zvyčajne polovičná, ako je veľkosť základného textu a názov „ruby“ pochádza od pomenovania písma veľkosti 5,5pt v britskej tlači, čo je približne polovičná veľkosť písma 10pt, ktorá sa bežne používa pre obyčajný text.
Pozrime sa však, čo všetko v tejto oblasti môžeme nastaviť v OpenOffice.org. Okrem vlastného „ruby“ textu je to jeho zarovnanie, ktoré môže byť vľavo, centrovane, vpravo, do bloku alebo do „vrúbkovaného“ bloku. Ďalej sa dá nastaviť znakový štýl „ruby“ textu a jeho umiestnenie nad alebo pod základný text. Pokiaľ vkladáte „ruby“ text do vertikálne písaných ázijských dokumentov, posledný parameter určuje umiestnenie „ruby“ textu vľavo alebo vpravo od základného textu.
Aby sme uvedené parametre mohli ľahko nastavovať, pripravíme si jednoduché dialógové pracovné okno, v ktorom budeme zadávať „ruby“ text. Okrem toho do dialógového okna vložíme prepínače, pomocou ktorých nastavíme umiestnenie „ruby“ textu nad alebo pod základný text. Ďalej do neho vložíme rozbaľovací zoznam, pomocou ktorého budeme nastavovať jeho zarovnanie. Pretože veľkosť, farba, písmo a pod. sa pri „ruby“ texte dá nastavovať iba pomocou znakového štýlu, umožníme jeho zadanie pomocou názvu. Pretože v OpenOffice.org je štandardne prednastavený znakový štýl „Ruby“, budeme ho inicializovať ako prednastavený priamo pri spúšťaní dialógového okna.
Vlastný „ruby“ text budeme následne vkladať okolo označeného textu. Aby sa nám pracovalo pohodlne, umožníme paralelnú prácu s dokumentom aj dialógovým oknom, takže po vložení „ruby“ textu sa toto okno nezatvorí – na to si nastavíme tlačidlo „Koniec“. Pretože pri spúšťaní dialógového okna môže označený text obsahovať aj „ruby“ text, budeme podľa jeho parametrov inicializovať príslušné nastavenia.
Na záver ešte uveďme, že vymazanie „ruby“ textu sa prevádza tak, že na jeho miesto vložíme prázdny reťazec. Pretože sa pri jeho nastavovaní pracuje so znakovými štýlmi, je vhodné, aby sme tieto zadefinovali skôr, ako ich zadáme do dialógového okna. Aby sme sa však v tomto neobmedzovali, v makre nebudeme kontrolovať, či príslušný štýl aj skutočne jestvuje a tým umožníme jeho definíciu aj neskôr.
dim dlgr as object
REM Makro pre nastavenie "RUBY" textu
sub Nastav_Ruby_Initiated
dim oKurzor as object
dim pom_text as string
oKurzor=ThisComponent.currentcontroller.getViewCursor() ' viditeľný kurzor
okurzor.RubyText=trim(dlgr.model.Text.text) ' Ruby text
if dlgr.model.Nad.state=1 then ' Pozícia
okurzor.RubyIsAbove=TRUE ' Ak je ruby text nad ostatným textom, tak sa nastavuje TRUE
else
okurzor.RubyIsAbove=FALSE ' Ak je ruby text pod ostatným textom, tak sa nastavuje FALSE
end if
pom_text=trim(dlgr.getControl("Zarovnanie").Text) ' Zarovnanie ruby textu
select case pom_text
case "LEFT"
okurzor.RubyAdjust=com.sun.star.text.RubyAdjust.LEFT ' do ľava
case "CENTER"
okurzor.RubyAdjust=com.sun.star.text.RubyAdjust.CENTER ' centrovane
case "RIGHT"
okurzor.RubyAdjust=com.sun.star.text.RubyAdjust.RIGHT ' do prava
case "BLOCK"
okurzor.RubyAdjust=com.sun.star.text.RubyAdjust.BLOCK ' do bloku
case "INDENT BLOCK"
okurzor.RubyAdjust=com.sun.star.text.RubyAdjust.INDENT_BLOCK ' do vrúbkovaného" bloku
end select
okurzor.RubyCharStyleName=trim(dlgr.model.Styl.text) ' Znakový štýl ruby textu
end sub
REM Makro, ktoré zneviditeľní dialóg – t.j. nastaví, že sa má ukončiť čakací cyklus (volané stlačením klávesy "Koniec" v dialógu)
sub Koniec_Ruby_Initiated
dlgr.setVisible(false )' Zneviditeľnenie dialógu
end sub
Rem Volanie dialógu a makra pre skrytie/odkrytie textu
sub Ruby_text
dim oKurzor as object
oKurzor=ThisComponent.currentcontroller.getViewCursor() ' viditeľný kurzor
DialogLibraries.LoadLibrary("JP_Skryty_text")
dlgr=CreateUnoDialog(DialogLibraries.JP_Skryty_text.Dialog_Ruby_text)
dlgr.model.Pod.State=1 ' Štandardne budeme vkladať ruby text pod ostatný text
dlgr.model.Nad.State=0
REM Ak je vložený ruby text, nastavíme parametre podľa neho
if okurzor.RubyText<>"" then
dlgr.model.Text.text=okurzor.RubyText ' Ruby text
if okurzor.RubyIsAbove then ' Pozícia ruby textu
dlgr.model.Pod.State=0
dlgr.model.Nad.State=1 ' Je nastavený ruby text nad
else
dlgr.model.Pod.State=1 ' Je nastavený ruby text pod
dlgr.model.Nad.State=0
endif
select case okurzor.RubyAdjust ' Zarovnanie ruby textu
case com.sun.star.text.RubyAdjust.LEFT ' do ľava
dlgr.model.Zarovnanie.Text="LEFT"
case com.sun.star.text.RubyAdjust.CENTER ' centrovane
dlgr.model.Zarovnanie.Text="CENTER"
case com.sun.star.text.RubyAdjust.RIGHT ' do prava
dlgr.model.Zarovnanie.Text="RIGHT"
case com.sun.star.text.RubyAdjust.BLOCK ' do bloku
dlgr.model.Zarovnanie.Text="BLOCK"
case com.sun.star.text.RubyAdjust.INDENT_BLOCK ' do vrúbkovaného" bloku
dlgr.model.Zarovnanie.Text="INDENT BLOCK"
end select
dlgr.model.Styl.text=okurzor.RubyCharStyleName ' Znakový štýl ruby textu
endif
dlgr.setVisible(true) ' zviditeľnenie dialógu – namiesto dlg.Execute(), aby sa dalo paralelne pracovať s textom
while dlgr.isVisible() ' Cyklus, ktorý čaká na stlačenie klávesy "Koniec" v dialógu (kým je dialóg viditeľný)
wait 500 ' Časová medzera 500 milisekúnd (0,5 sec) na to, aby sa dalo paralelne pracovať s dokumentom
wend
dlgr.dispose() ' Zatvorenie dialógu
end sub
