Makrá v OpenOffice.org – typografická kontrola textu (I)

Mnohí používatelia potrebujú pri svojej práci vyhľadať a označiť typografické chyby v dokumente, ktorý pripravoval niekto iný. Môže sa jednať nielen o učiteľov, ale aj o bežných používateľov, ktorým už „lezie na nervy“ nekonečné vysvetľovanie týchto pravidiel iným. Pre takéto účely sa hodí makro, ktoré takéto chyby (pravdaže, nie všetky) vyhľadá a označí.

Pozrime sa na úvod na to, aké typografické chyby sa v dokumentoch dajú pomerne ľahko automaticky nájsť a označiť. V základnom členení ich môžeme rozdeliť do troch skupín – nadbytočné medzery, chýbajúce medzery a ostatné chyby.

V prípade nadbytočných medzier dokážeme programovo vyhľadať viacnásobné medzery a tabelátory; medzery a tabelátory na začiatku a na konci odsekov; medzery medzi zátvorkou, úvodzovkou a textom; medzery pred interpunkčnými znamienkami. V prípade chýbajúcich medzier dokážeme vyhľadať chýbajúce medzery za interpunkčným znamienkom – teda medzi interpunkčnými znamienkami a textom. Napokon, ako ostatné chyby dokážeme vyhľadať prázdne odseky.



Pri hľadaní typografických chýb sa však vyskytujú aj výnimky, kedy uvedené možnosti chyby nie sú – napr. v internetových odkazoch či mailových adresách sa nesmie vyskytovať medzera za interpunkčným znamienkom, čo je však v bežnom texte chyba. Preto je vhodné, aby si každý mohol nastaviť, aké chyby sa vlastne budú hľadať a označovať. Na tento účel si preto zadefinujeme dialóg, v ktorom budeme nastavovať, ktoré chyby sa majú hľadať a zároveň umožníme, aby si tieto nastavenia uložil, aby ich mohol kedykoľvek používať bez ďalšieho nastavovania.

Pretože chyby chceme aj označiť, pričom každý môže chcieť používať svoj vlastný spôsob označovania, v dialógu umožníme aj toto nastavenie – chyby umožníme prečiarknuť a podčiarknuť, pričom umožníme výber zo všetkých druhov prečiarkovania a podčiarkovania, ktoré OpenOffice.org poskytuje. Podobne ako pri druhoch chýb aj v tejto časti umožníme, aby si používateľ mohol tieto nastavenia uložiť.



A aby sme hneď vedeli, koľko chýb (ak vôbec) sa v dokumente vyskytuje, budeme ich počet vypisovať. Pravdaže, ako sme naznačili v problematike mailových adries, vypísaný nenulový počet chýb nemusí ešte znamenať, že v dokumente je typografická chyba a, naopak, vypísaný nulový počet chýb nemusí znamenať, že sa v dokumente nenachádza iná chyba. To si však už musí vyriešiť každý sám podľa toho, aký dokument posudzuje.



Pretože makrá sú trochu rozsiahlejšie (sú riešené ako rozšírenie, ktoré môže byť jazykovo lokalizované), ich zdrojové texty uvedieme v troch častiach tohto seriálu. Pre začiatok si dnes uvedieme definície hlavných premenných, funkcie pre jazykovú lokalizáciu a načítavanie definícií zo súboru.

dim CoKontrolovat%(9), CoNastavit%(1), AkoNastavit$(1)
 dim sOznam1$, sOznam2$, sOznam3$
 dim oDlg
 
 REM Funkcia pre zistenie jazyka OO.o
 function Jazyk_OOo as string
  dim ConfigProvider, MasterKey as object
  dim NodePath(0) as new com.sun.star.beans.PropertyValue
   
  NodePath(0).Name = "nodepath"
  NodePath(0).Value = "org.openoffice.Setup/L10N/"
  
  ConfigProvider = createUnoService("com.sun.star.configuration.ConfigurationProvider")
  MasterKey = ConfigProvider.createInstanceWithArguments("com.sun.star.configuration.ConfigurationAccess", NodePath())
  Jazyk_OOo = left(MasterKey.getByName("ooLocale"), 2) '"sk", "cs", ...
 end function
 
 REM Procedúra pre nastavenie textov výpisu
 Sub Set_jazyk_vypisu(sNazov)
  dim riadok, premenna, definicia as string
  dim rovna as integer
  dim sf, inStream, inFile ' Pre čítanie z lokalizačného súboru
 
  on error resume next
  
  if fileexists(sNazov) then ' Ak lokalizačný súbor existuje, tak načítame definície do premenných
   sf = createUnoService("com.sun.star.ucb.SimpleFileAccess")
   inStream = sf.openFileRead(sNazov) 
   inFile = createUnoService("com.sun.star.io.TextInputStream") 
   inFile.InputStream = inStream
   inFile.Encoding = "UTF-8" ' lokalizačný súbor musí byť v UTF-8, inak nebude dobrá diakritika
   
   Do While not inFile.IsEOF
    riadok = inFile.readLine ' namiesto Line Input #subor, riadok
    rovna=instr(riadok,"=")
    if rovna<>0 then
     premenna=trim(left(riadok,rovna-1)) ' Budeme ignorovať medzery
     definicia=trim(right(riadok,len(riadok)-rovna))
     select case premenna
      case "Oznam1"
       sOznam1=definicia+" "
      case "Oznam2"
       sOznam2=" "+definicia
      case "Oznam3"
       sOznam3=Definicia
     end select
    end if
   loop 
   ' Zatvorenie definičného súboru – namiesto close #subor
   inStream.closeInput
   inFile.closeInput
  end if
 end sub
 
 REM Procedúra pre nastavenie jazyka dialógu
 Sub Set_jazyk_Dialogu(oDlg, sNazov, sZahlavie)
  dim riadok, premenna, definicia as string
  dim rovna as integer
  dim sf, inStream, inFile ' Pre čítanie z lokalizačného súboru
 
  on error resume next
  
  if fileexists(sNazov) then ' Ak lokalizačný súbor existuje, tak načítame definície do premenných
   sf = createUnoService("com.sun.star.ucb.SimpleFileAccess")
   inStream = sf.openFileRead(sNazov) 
   inFile = createUnoService("com.sun.star.io.TextInputStream") 
   inFile.InputStream = inStream
   inFile.Encoding = "UTF-8" ' lokalizačný súbor musí byť v UTF-8, inak nebude dobrá diakritika
   
   Do While not inFile.IsEOF
    riadok = inFile.readLine ' namiesto Line Input #subor, riadok
    rovna=instr(riadok,"=")
    if rovna<>0 then
     premenna=trim(left(riadok,rovna-1)) ' Budeme ignorovať medzery
     definicia=trim(right(riadok,len(riadok)-rovna))
     if premenna=sZahlavie then
      oDlg.Title=definicia
     else
      oDlg.model.getByName(premenna).setpropertyvalue("Label",definicia)
     end if
    end if
   loop 
   ' Zatvorenie definičného súboru – namiesto close #subor
   inStream.closeInput
   inFile.closeInput
  end if
 end sub
 
 REM Procedúra pre inicializáciu kontrolovaných častí a ich označovania zo súboru
 sub InitKontrolu
  dim riadok, premenna, definicia as string
  dim rovna as integer
  dim sf, inStream, inFile ' Pre čítanie z lokalizačného súboru
  dim i%
  dim sNazov$, kde$
  
  REM Inicializácia, ak by neexistoval súbor s nastaveniami
  for i=0 to 9
   CoKontrolovat(i)=1
  next i
  CoNastavit(0)=0
  CoNastavit(1)=1
  AkoNastavit(0)="None" ' Žiadne prečiarknutie
  AkoNastavit(1)="Wave" ' Podčiatknutie vlnovkou
  
  kde=basiclibraries.getLibraryLinkURL("JP_typokontrola_textu") ' Adresár, kde je rozšírenie nainštalované
  sNazov=left(kde,len(kde)-10)+"jp_typokontrola_set.txt" ' Súbor s nastaveniami
  
  on error resume next
  
  if fileexists(sNazov) then ' Ak súbor existuje, tak načítame definície do premenných
   sf = createUnoService("com.sun.star.ucb.SimpleFileAccess")
   inStream = sf.openFileRead(sNazov) 
   inFile = createUnoService("com.sun.star.io.TextInputStream") 
   inFile.InputStream = inStream
   inFile.Encoding = "UTF-8" ' lokalizačný súbor musí byť v UTF-8, inak nebude dobrá diakritika
   
   Do While not inFile.IsEOF
    riadok = inFile.readLine ' namiesto Line Input #subor, riadok
    rovna=instr(riadok,"=")
    if rovna<>0 then
     premenna=trim(left(riadok,rovna-1)) ' Budeme ignorovať medzery
     definicia=trim(right(riadok,len(riadok)-rovna))
     i=val(right(premenna,1))
     premenna=left(premenna,1)
     select case premenna
      case "K" ' K5=1, K6=0 ...
       CoKontrolovat(i)=val(definicia)
      case "N" ' N0=0, N1=1
       CoNastavit(i)=val(definicia)
      case "A" ' A0=None, A1=Wave
       AkoNastavit(i)=trim(definicia)
     end select
    end if
   loop 
   ' Zatvorenie definičného súboru – namiesto close #subor
   inStream.closeInput
   inFile.closeInput
  end if
 end sub